[plevel 1]
aile

[function ailetalep]
if (<src.account.plevel> > 1)
    if (<dlist._Aileler.count> >= 1) 
         sdialog d_aile_onay
    else
        src.sysmessage @0842,,1 Onay bekleyen aile başvurusu yok.
    endif
return 1
endif

[function aile]
local._isAile = <getargvx 2,<src.tag._aile>>
if !(<src.dtag._aile>)
    src.sysmessage @0842,,1 Bir aileniz bulunmuyor.
elif (<local._isAile>)
    src.sysmessage @0842,,1 Aile başvurunuz henüz onaylanmamış.
    src.sysmessage @0842,,1 Olumlu yada olumsuz bilgilendirileceksiniz.
elif (<src.dtag._aile>)
    sdialog d_aile
endif

[itemdef i_deed_aile]
id = i_deed
name = Aile Belgesi
value = 212212
type = t_normal
weight = 1

on=@click
    message @0481,,1 <name>
return 1

on=@create 
    attr = 04
    color = 0842

on=@dclick
    if (<topobj.uid> != <src>)
        src.sysmessage @0842,,1 Çantanızda olması gerekiyor.
    elif !(<isempty <src.tag._Aile>>)
            src.sysmessage @0842,,1 Mevcut bir aileniz bulunmakta.
    else
        sdialog d_aile_kurulum
    endif
return 1

[dialog d_aile_kurulum]
100,50
resizepic 100 100 83 400 240
gumppictiled 120 131 355 1 5058
dtext 265 113 0481 Aile Kurulum
gumppic 210 255 2446
button 280 287 2151 2153 1 0 1
dtextentrylimited 225 257 200 20 1152 0 10 ?
dtext 120 140 0481 1. Türkçe karakter kullanımına izin verilmez.
dtext 120 165 0481 2. Sembol ve Rakam kullanımlarına izin verilmez.
dtext 120 190 0481 3. Boşluk kullanımına izin verilmez.
dtext 120 215 0481 4. En az 3 en fazla 10 harf olabilir.

[dialog d_aile_kurulum button]
on=1
if (<src.dtag._Aile>)
	src.Sysmessage @0842,,1 Mevcut bir aileniz bulunmakta.
elif !(<src.findid.i_deed_aile>)
	src.Sysmessage @0842,,1 Çantanızda aile belgesi yok.
elif (<isempty <argtxt[0]>>)
	src.Sysmessage @0842,,1 Aile ismini boş bıraktınız.
elif (<eval(strlen(<argtxt[0]>))> < 3) 
	src.Sysmessage @0842,,1 Aile ismi en az 3 en fazla 10 karakter olabilir.
elif (<badfamilynames <argtxt[0]>>)
	src.Sysmessage @0842,,1 Hatalı karakterler var.
else
	src.tag._Aile = <argtxt[0]>,<serv.rtime.format %x>
	list._Aileler.add = <src>
	remove
	src.Sysmessage @0481,,1 Aile başvurunuz onaya gönderildi.
	src.s Yetkiliye Duyuru: Yeni aile talebi, <src.name> / <src.tag._Aile>
	return 1
endif

[dialog d_aile_onay]
100,50
resizepic 80 100 83 420 245
gumppictiled 111 131 360 1 5058
dtext 240 113 0481 Onay Bekleyen Aileler
dtext 170 140 0842 Aile            Kurucu           Tarih
dorigin 170 140
for 0 <eval <list._aileler.count>-1>
ref1 = <list._aileler.<dlocal._for>>
dtext +0 *25 0481 <getargvx 1,<ref1.tag._aile>>
dtext +117 *0 0481 <ref1.name>
dtext +243 *0 0481 <getargvx 2,<ref1.tag._aile>>
button -34 -2 4023 4024 1 0 <eval <dlocal._for>+1>
button -70 -2 4017 4018 1 0 <eval <dlocal._for>+100>
endfor

[dialog d_aile_onay button]
on=1,99
local._aile = <eval <dargn1>-1>
ref1 = <list._aileler.<dlocal._aile>>
if <ref1.tag0._aile>
	src.sysmessage @38,,1 <ref1.name> mevcut bir aileye mensup
	list._aileler.<dlocal._aile>.remove
	ref1.sysmessage @0842,,1 Bir aileye mensup olduğunuz için aile talebiniz silindi.
	return 1
endif
if (<ref1.isonline>)
    ref1.sysmessage @0842,,1 Onayda olan aile başvurunuz onaylandı.
endif
        ref1.tag.name.suffix=" <getargvx 1,<ref1.tag._aile>>"
        ref1.tag._aile = <ref1>
        list._aile_<ref1>.add = <ref1>
        list._aileler.<dlocal._aile>.remove
        src.sysmessage @0481,,1 Aile başvurusunu onayladınız.
        src.aile
return 1

on=100,200
local.aile = <eval <dargn1>-100>
ref1 = <list._aileler.<dlocal._aile>>
if (<ref1.isonline>)
    ref1.sysmessage @0842,,1 Onayda olan aile başvurunuz onaylanmadı.
endif
    serv.newitem = i_deed_aile,1,<ref1.findlayer.21>
    ref1.tag._aile = 
    list._aileler.<dlocal._aile>.remove
    src.sysmessage @0481,,1 Aile başvurusunu reddettiniz.
    src.aile
return 1

[dialog d_aile]
100,50
resizepic 80 100 83 420 330
gumppictiled 111 131 360 1 5058
dtext 220 113 0481 <tag.name.suffix> Aile Menüsü

page 1
gumppic 195 310 114
ref1 = <src.tag._Aile>
ref2 = <list._aile_<ref1>.0>
gumppic 285 150 2153 
gumppic 285 195 2153
gumppic 285 240 2153
dText 320 153 0481 Aile Başkanı: <ref2.name>
dText 320 198 0481 Aile Üye Sayısı: <list._aile_<ref1>.count> / 7

for 0 <eval <dlist._aile_<ref1>.count>-1>
ref3 = <list._aile_<ref1>.<dlocal._for>>
  if (<ref3.isOnline>)
	local._isOnline ++
  endif
endfor
dText 320 243 044 Çevrimiçi Üye Sayısı: <dlocal._isOnline>

button 100 150 2151 2153 0 2 2
dtext 135 153 0481 Üyeleri Görüntüle

if (<ref2> != <src>)
    // button 100 195 2151 2153 1 0 5000
    // dtext 135 198 0481 Eklenecek.
    button 100 195 2151 2153 1 0 6000
    dtext 135 198 0481 Aileden Ayrıl!
else
    button 100 195 2151 2153 1 0 4000
    dtext 135 198 0481 Aileye Üye Ekle
    button 100 240 2151 2153 1 0 3000
    dtext 135 243 0481 Aileyi Dağıt!
endif

if (<src.dctag._ailedagit>)
    button 97 278 4017 4018 1 0 3001
    button 130 278 4023 4024 1 0 3002
    dtext 165 281 0481 Onaylıyor musunuz?
endif

if (<src.dctag._ailedenayril>)
    button 97 278 4017 4018 1 0 6001
    button 130 278 4023 4024 1 0 6002
    dtext 165 281 0481 Onaylıyor musunuz?
endif

page 2
ref1 = <src.tag._Aile>
ref2 = <list._aile_<ref1>.0>
dText 110 140 60 İsim                  Kills                 Deaths
dorigin 100 140
for 0 <eval <list._aile_<ref1>.count>-1>
ref3 = <list._aile_<ref1>.<dlocal._for>>
if (<ref2> != <src>)
gumppic -2 *30 211 38
else
button -2 *30 <qval (<dlocal._for>==<src.dctag._isbutton>)?211 210:210 211> 1 0 <eval <dlocal._for>+1000>
endif
dtext +25 *0 0481 <ref3.name>
dtext +177 *0 0481 <ref3.kills>
dtext +340 *0 0481 <ref3.deaths>
endfor

button 130 380 2151 2153 1 0 999
dtext 165 384 0481 Ana Sayfa

if (<ref2> == <src>)
  button 268 380 2151 2153 1 0 10000
  dtext 303 383 0481 Seçilen üyeyi aileden çıkar.
endif

[dialog d_aile button]
on=0
    src.ctag._isbutton = 
    src.ctag._ailedagit =
    src.ctag._ailedenayril = 

on=999
src.ctag._isbutton = 
sdialog d_aile 

on=1000,2000
src.ctag._isbutton = <eval <dargn1>-1000>
sdialog d_aile 2

on=10000
if (<src.dctag._isbutton> == 0) || !(<src.dctag._isbutton>)
    src.sysmessage @0842,,1 Kendinizi aileden atamazsınız.
    src.sysmessage @0842,,1 Eğer isterseniz aileyi dağıtabilirsiniz.
    sdialog d_aile 2
    return 1
endif
ref1 = <src.tag._aile>
ref2 = <list._aile_<ref1>.<src.dctag._isbutton>>
if (<ref2.isonline>)
  src.sysmessage @0842,,1 <src.name>, tarafından <src.tag.name.suffix>, ailesinden çıkartıldınız.
endif
ref2.tag._aile = 
ref2.tag.name.suffix =
src.sysmessage @0481,,1 <ref2.name>, aileden çıkartıldı.
list._aile_<ref1>.<src.dctag._isbutton>.remove
sdialog d_aile 2
return 1

on=3000
src.ctag._ailedagit = 1
sdialog d_aile

on=3001
src.ctag._ailedagit = 
sdialog d_aile

on=3002
local._aile = <src.tag.name.suffix>
local._aile = <src.tag._aile>
ref1 = <local._aile>
for 0 <eval <list._aile_<ref1>.count>-1>
ref2 = <list._aile_<ref1>.<dlocal._for>>
if (<ref2.isonline>)
    if (<ref2> != <src>)
        ref2.sysmessage @0842,,1 <local._aile>, ailesi <src.name>, tarafından dağıtılmıştır.
    endif
endif
ref2.tag.name.suffix = 
ref2.tag._aile = 
endfor
    src.sysmessage @0842,,1 Aileyi dağıttınız.
    list._aile_<ref1>.clear
    src.ctag._ailedagit = 

on=4000
src.targetf f_aile_uye
src.sysmessage @0481 Hedef?

on=6000
src.ctag._ailedenayril = 1
sdialog d_aile

on=6001
src.ctag._ailedenayril = 
sdialog d_aile

on=6002
ref1 = <src.tag._aile>
list._aile_<ref1>.<list._aile_<ref1>.findelem <src>>.remove
src.tag.name.suffix =
src.tag._aile = 
src.ctag._ailedenayril = 
src.sysmessage @0481,,1 Aileden ayrıldınız.
return 1

[dialog d_aile_uye]
100,50
resizepic 80 100 83 420 300
gumppictiled 111 131 360 1 5058
dtext 220 113 0481 <tag.name.suffix> Aile Menüsü
dhtmlgump 120 165 325 50 0 0 <def.bfont_white>Merhaba <def.bfont_lgreen><src.name>, <def.bfont_lyellow><tag.name.suffix><def.bfont_white>, ailesinin kurucusu <name><def.bfont_white>, <def.bfont_lred>50.000gp's <def.bfont_white> ücret karşılığında ailesine katılmanız için size bir istek gönderdi.
gumppic 142 225 2
button 205 340 2151 2153 1 0 1
dtext 240 343 0481 Daveti kabul ediyorum.

[dialog d_aile_uye button]
on=1
if !(<src.gold> >= 50000)
    src.sysmessage @0842,,1 50.000gp's gerekiyor.
    sysmessage @0842,,1 <src.name>, için 50.000gp's gerekiyor.
    return 1
endif
ref1 = <uid>
src.tag._aile = <ref1>
list._aile_<ref1>.add = <src>
src.tag.name.suffix="<ref1.tag.name.suffix>"
src.gold -= 50000
ref1.sysmessage @0842,,1 <src.name>, aile davetinizi kabul etti.
src.sysmessage @0481,,1 <src.tag.name.suffix>, ailesine katıldınız.
return 1

[function f_aile_uye]
if (<argo.isdialogopen.d_aile_uye>)
	src.sysmessage @0842,,1 <argo.name> için şuanda bir istek mevcut!
elif !(<argo.isplayer>)
    src.sysmessage @0842,,1 Sadece oyuncular olabilir.
elif (<argo.dtag._aile>)
	src.sysmessage @0842,,1 <argo.name> zaten bir aileye üye.
else
	trysrc <argo> dialog d_aile_uye
    src.sysmessage @0481,,1 Davetiniz gönderildi.
endif
return 1

[function ac]
if (<isempty <args>>)
  src.sysmessage @38,,1 Boş mesaj yollayamzsınız.
 return 1
 endif
if !(<isempty <src.tag._Aile>>)
serv.allclients ac_chat <args>
endif

[function ac_chat]
if (<tag0._aile> == <src.tag0._aile>)
    sysmessage @0850,,1 <src.name>: <args>
endif

[EOF]